USB-C PD Bench Supply with Power Meter

#include <Wire.h>
#include <WiFi.h>
#include <WebServer.h>

const int OUT_PIN = 4;                 // ET-MD08 IN1
const uint8_t INA = 0x40;
const float SHUNT = 0.015;             // ET-P15 shunt
const float CURRENT_LSB = 0.0002;      // 0.2 mA per bit (±5.4 A range)

WebServer server(80);
bool outputOn = false, tripped = false;
float limitA = 2.0, volts, amps, watts, wh = 0;

void inaWrite(uint8_t reg, uint16_t v) {
  Wire.beginTransmission(INA); Wire.write(reg); Wire.write(v >> 8); Wire.write(v & 0xFF); Wire.endTransmission();
}
int16_t inaRead(uint8_t reg) {
  Wire.beginTransmission(INA); Wire.write(reg); Wire.endTransmission(false);
  Wire.requestFrom(INA, (uint8_t)2);
  return (int16_t)((Wire.read() << 8) | Wire.read());
}

void setOutput(bool on) { outputOn = on; digitalWrite(OUT_PIN, on); }

void handleRoot() {
  if (server.hasArg("on"))    { tripped = false; setOutput(true); }
  if (server.hasArg("off"))   setOutput(false);
  if (server.hasArg("limit")) limitA = server.arg("limit").toFloat();
  if (server.hasArg("reset")) wh = 0;

  String s = "<!doctype html><meta name=viewport content='width=device-width'><meta http-equiv=refresh content=2>"
             "<body style='font:18px sans-serif;max-width:420px;margin:24px auto'><h2>USB-C bench supply</h2>";
  s += "<p style='font-size:30px;margin:0'>" + String(volts, 2) + " V &middot; " + String(amps, 3) + " A</p>";
  s += "<p>" + String(watts, 2) + " W &middot; " + String(wh, 3) + " Wh</p>";
  s += String("<p><b>") + (tripped ? "TRIPPED" : outputOn ? "Output ON" : "Output off") + "</b></p>";
  s += "<p><a href='/?on=1'>Turn on</a> &nbsp; <a href='/?off=1'>Turn off</a> &nbsp; <a href='/?reset=1'>Reset Wh</a></p>";
  s += "<form>Trip at <input name=limit size=4 value='" + String(limitA, 2) + "'> A <button>Set</button></form>";
  server.send(200, "text/html", s);
}

void setup() {
  pinMode(OUT_PIN, OUTPUT);
  setOutput(false);
  Serial.begin(115200);
  Wire.begin(8, 9);

  inaWrite(0x00, 0x4527);              // 16 averages, 1.1 ms conversions, continuous
  inaWrite(0x05, (uint16_t)(0.00512 / (CURRENT_LSB * SHUNT)));   // calibration

  WiFi.softAP("ET-Bench", "electrotrical");
  server.on("/", handleRoot);
  server.begin();
}

void loop() {
  static unsigned long last = 0;
  if (millis() - last >= 50) {
    float dt = (millis() - last) / 3600000.0;
    last = millis();
    volts = (uint16_t)inaRead(0x02) * 0.00125;       // bus voltage, 1.25 mV/bit
    amps  = inaRead(0x04) * CURRENT_LSB;
    watts = (uint16_t)inaRead(0x03) * 25 * CURRENT_LSB;
    if (outputOn) wh += watts * dt;
    if (outputOn && amps > limitA) { setOutput(false); tripped = true; }
  }
  server.handleClient();
}